Function ReplaceRemoteUrl(ByVal strContent)
    Dim regEx
    Dim RemoteFiles, RemoteFile, RemoteFileUrl
    Dim SavedFiles
    Dim D_Name, F_Name
    D_Name = Year(now)&Month(now)
    createfolder("attachments/"&D_Name)
    SavedFiles = "|"
    Set regEx = New RegExp
    regEx.IgnoreCase = True
    regEx.Global = True
    regEx.Pattern = "((http|https)://(.+?)\.(gif|jpg|jpeg|jpe|bmp|png))"
    Set RemoteFiles = regEx.Execute(strContent)
    For Each RemoteFile In RemoteFiles
        RemoteFileUrl = RemoteFile.Value
        If InStr(SavedFiles, "|" & RemoteFileUrl & "|") = 0 or InStr(RemoteFileUrl, SiteName) = 0 Then
            SavedFiles = SavedFiles & RemoteFileUrl & "|"
            F_Name = Year(Now)&Month(Now)&Day(Now)&Hour(Now)&Minute(Now)&Second(Now) & "_" & RemoteFileUrl
            If SaveRemoteFile(RemoteFileUrl, "attachments/"&D_Name&"/"&F_Name) = True Then
                '写入数据库
                Conn.Execute("insert into blog_Files (FilesPath) values ('attachments/"&D_Name&"/"&F_Name&"')")
                dim FilePath
                FilePath = "download.asp?id=" & Conn.Execute("select id from blog_Files order by id desc")(0)
                strContent = Replace(strContent, RemoteFileUrl, FilePath)
            End If
        End If
    Next
    Set RemoteFiles = Nothing
    Set regEx = Nothing
    ReplaceRemoteUrl = strContent
End Function

Function SaveRemoteFile(RemoteFileUrl, LocalFileName)
    On Error Resume Next
    Dim Ads, Retrieval, GetRemoteData
    Set Retrieval = Server.CreateObject("Microsoft.XMLHTTP")
    With Retrieval
        .Open "Get", RemoteFileUrl, False, "", ""
        .Send
        GetRemoteData = .ResponseBody
    End With
    If Err.Number <> 0 Then
        Err.Clear
        SaveRemoteFile = False
        Exit Function
    End If
    Set Retrieval = Nothing
    Set Ads = Server.CreateObject("Adodb.Stream")
    With Ads
        .Type = 1
        .Open
        .Write GetRemoteData
        .SaveToFile Server.MapPath(LocalFileName), 2
        .Cancel
        .Close
    End With
    Set Ads = Nothing
    If Err.Number <> 0 Then
        Err.Clear
        SaveRemoteFile = False
    Else
        SaveRemoteFile = True
    End If
End Function